Voice-Interactive LED Light Panel

#include <SoftwareSerial.h>
#include <FastLED.h>

SoftwareSerial mySerial(10, 11); // RX, TX
String value;

#define LED_PIN 9
#define NUM_LEDS 64
#define BRIGHTNESS 100

CRGB leds[NUM_LEDS];  // FastLED 控制数组

// 8x8矩阵中的爱心
const int heart[] = {
  9, 10, 13, 14, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25,
  26, 27, 28, 29, 30, 31, 33, 34, 35, 36, 37, 38, 42, 43,
  44, 45, 51, 52
};

void setup() {
  mySerial.begin(9600); // 软件串口用于语音模块

  FastLED.addLeds<WS2812, LED_PIN, GRB>(leds, NUM_LEDS); // 初始化灯带
  FastLED.setBrightness(BRIGHTNESS); // 设置亮度
  fill_solid(leds, NUM_LEDS, CRGB::Black); //默认关闭
  FastLED.show();
}

void loop() { //主循环持续监听语音串口
  if (mySerial.available()) {
    value = mySerial.readString();
    value.trim();
    handleCommand(value);
  }
}

void handleCommand(String cmd) { //接收到字符指令后分发给对应灯效函数
  if (cmd == "rainbow") {
    rainbowEffect();
  }
  else if (cmd == "warm") {
    warmLight();
  }
  else if (cmd == "cold") {
    coldLight();
  }
  else if (cmd == "close") {
    turnOff();
  }
  else if (cmd == "heart") {
    heartEffect();
  }
  else {
    // 如果收到未知命令
    turnOff();
  }
}

// 彩虹灯
void rainbowEffect() {
  static uint8_t hue = 0; //色调值 hue 是 0~255 的环形值，代表 HSV 色彩模型中的色相角度。

  while (true) {
    // 检查 mySerial 是否收到"打断"指令
    if (mySerial.available()) {
      String interruptCmd = mySerial.readString();
      interruptCmd.trim();

      if (interruptCmd == "close" || interruptCmd == "warm" || interruptCmd == "cold" || interruptCmd == "heart") {
        handleCommand(interruptCmd);  // 执行其他指令
        break; // 跳出彩虹效果，回到主 loop
      }
    }

    for (int i = 0; i < NUM_LEDS; i++) { // 正向扫描灯珠（彩虹推进）
      leds[i] = CHSV(hue++, 255, 255); // 色调渐变，即在颜色轮上生成一个鲜艳纯色（红→橙→绿→蓝→紫→红...）
      FastLED.show();
      fadeall(); // 所有灯珠略微变暗
      delay(10);
    }

    for (int i = NUM_LEDS - 1; i >= 0; i--) { // 反向扫描灯珠（回扫）
      leds[i] = CHSV(hue++, 255, 255);
      FastLED.show();
      fadeall();
      delay(10);
    }

    delay(100); // 循环之间的缓冲延时
  }
}

// 淡出函数
void fadeall() {
  for (int i = 0; i < NUM_LEDS; i++) {
    leds[i].nscale8(250); // 渐暗
  }
}

// 暖光
void warmLight() {
  fill_solid(leds, NUM_LEDS, CRGB(255, 150, 50));
  FastLED.show();
}

// 冷光
void coldLight() {
  fill_solid(leds, NUM_LEDS, CRGB(150, 200, 255));
  FastLED.show();
}

// 关闭灯效
void turnOff() {
  fill_solid(leds, NUM_LEDS, CRGB::Black);
  FastLED.show();
}

// 爱心效果
void heartEffect() {
  bool on = true;
  while (true) {
    // 检查是否接收到指令来停止闪烁
    if (mySerial.available()) {
      String interruptCmd = mySerial.readString();
      interruptCmd.trim();

      if (interruptCmd == "close" || interruptCmd == "warm" || interruptCmd == "cold" || interruptCmd == "rainbow") {
        handleCommand(interruptCmd);  // 执行其他指令
        break; // 跳出爱心效果，回到主 loop
      }
    }

    // 先清除所有 LED
    fill_solid(leds, NUM_LEDS, CRGB::Black); // 所有 LED 关闭

    // 绘制红色实心爱心
    for (int i = 0; i < sizeof(heart) / sizeof(heart[0]); i++) {
      leds[heart[i]] = on ? CRGB::Red : CRGB::Black;
    }
    FastLED.show();
    delay(500);  // 每次切换后延时，控制闪烁速度
    on = !on; // 翻转灯光状态，实心红色和关闭
  }
}

#include "asr.h"
extern "C"{ void * __dso_handle = 0 ;}
#include "setup.h"
#include "myLib/asr_event.h"
#include "HardwareSerial.h"

uint32_t snid;
void ASR_CODE();

//{speak:阿文-温和男声,vol:10,speed:10,platform:haohaodada}
//{playid:10001,voice:}
//{playid:10002,voice:}

/*描述该功能...
*/
void ASR_CODE(){
  switch (snid) {
   case 1:
    Serial.print("rainbow");
    break;
   case 2:
    Serial.print("warm");
    break;
   case 3:
    Serial.print("cold");
    break;
   case 4:
    Serial.print("heart");
    break;
   case 5:
    Serial.print("close");
    break;
  }

}

void hardware_init(){
  setPinFun(13,SECOND_FUNCTION);
  setPinFun(14,SECOND_FUNCTION);
  Serial.begin(9600);
  vTaskDelete(NULL);
}

void setup()
{
  set_wakeup_forever();
  //{ID:0,keyword:"命令词",ASR:"罗纳尔多",ASRTO:"hello Imran"}
  //{ID:1,keyword:"命令词",ASR:"打开彩虹灯",ASRTO:"彩虹灯打开了"}
  //{ID:2,keyword:"命令词",ASR:"暖光",ASRTO:"暖光打开了"}
  //{ID:3,keyword:"命令词",ASR:"冷光",ASRTO:"冷光打开了"}
  //{ID:4,keyword:"命令词",ASR:"爱心",ASRTO:"给你爱心"}
  //{ID:5,keyword:"命令词",ASR:"关灯",ASRTO:"siuuu"}
  dpmu_set_io_pull(pinToFun[13],DPMU_IO_PULL_DISABLE);
  dpmu_set_io_open_drain(pinToFun[13],ENABLE );
}